IOController_i.idl

См. документацию.

/* This file is part of the UniSet project
 * Copyright (c) 2002 Free Software Foundation, Inc.
 * Copyright (c) 2002 Pavel Vainerman
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
 */
// --------------------------------------------------------------------------
// --------------------------------------------------------------------------
#ifndef BaseIOController_i_IDL_
#define BaseIOController_i_IDL_
// --------------------------------------------------------------------------
#include "../UniSetTypes/UniSetTypes_i.idl"
#include "../UniSetTypes/ObjectsManager_i.idl"
// --------------------------------------------------------------------------------------------------------------

interface IOController_i : ObjectsManager_i 
{
    // исключения
    
    exception NameNotFound
    {   
        string err;
    };

    exception IOBadParam
    {   
        string err;
    };


    exception Undefined
    {   
    };


    struct SensorInfo
    {
        UniSetTypes::ObjectId id;   
        UniSetTypes::ObjectId node; 
    };

    boolean getState(in SensorInfo si) raises(NameNotFound,Undefined);
    long getValue(in SensorInfo si) raises(NameNotFound,Undefined);
    void setState(in SensorInfo si, in boolean state,
                    in UniSetTypes::ObjectId sup_id) raises(NameNotFound);
    void setValue(in SensorInfo si, in long value,
                    in UniSetTypes::ObjectId sup_id) raises(NameNotFound);

    void saveState(in SensorInfo si, in boolean state, in UniversalIO::IOTypes type,
                        in UniSetTypes::ObjectId sup_id) raises(IOBadParam,NameNotFound);
    void saveValue(in SensorInfo si, in long value, in UniversalIO::IOTypes type, 
                        in UniSetTypes::ObjectId sup_id) raises(IOBadParam,NameNotFound);

    // установка неопределённого состояния
    // (пока работает только для аналоговых датчиков)
    void setUndefinedState(in SensorInfo si, in boolean undefined, in UniSetTypes::ObjectId sup_id ) 
                            raises(NameNotFound);

    // fast version (не вырабатывает исключения)
    oneway void fastSaveState(in SensorInfo si, in boolean state, in UniversalIO::IOTypes type,
                        in UniSetTypes::ObjectId sup_id);
    oneway void fastSaveValue(in SensorInfo si, in long value, in UniversalIO::IOTypes type, 
                        in UniSetTypes::ObjectId sup_id);

    oneway void fastSetState(in SensorInfo si, in boolean state, in UniSetTypes::ObjectId sup_id);
    oneway void fastSetValue(in SensorInfo si, in long value, in UniSetTypes::ObjectId sup_id);

    UniversalIO::IOTypes getIOType(in SensorInfo si) raises(NameNotFound);

    // --- Интерфейс для конфигурирования ---

    long getRawValue( in SensorInfo si ) raises(NameNotFound);
    
    struct CalibrateInfo
    {
        long minRaw;        
        long maxRaw;        
        long minCal;        
        long maxCal;        
        long sensibility;   
        short precision;    
    };

    void calibrate( in SensorInfo si, in CalibrateInfo ci, in UniSetTypes::ObjectId adminId ) raises(NameNotFound);
    CalibrateInfo getCalibrateInfo( in SensorInfo si ) raises(NameNotFound);

    // --- Интерфес получения информации о всех датчиках ---

    struct DigitalIOInfo
    {
        boolean state;              
        boolean undefined;          
        boolean blocked;            
        boolean real_state;         
        UniversalIO::IOTypes type;  
        long priority;              
        IOController_i::SensorInfo si;
        boolean default_val;        
        long tv_sec;    
        long tv_usec;   
    };

    struct AnalogIOInfo
    {
        long value;                 
        boolean undefined;          
        boolean blocked;            
        long real_value;            
        UniversalIO::IOTypes type;  
        long priority;              
        IOController_i::SensorInfo si;
        long default_val;           
        CalibrateInfo ci;           
        long tv_sec;                
        long tv_usec;               
    };

    typedef sequence<AnalogIOInfo> ASensorInfoSeq;
    typedef sequence<DigitalIOInfo> DSensorInfoSeq;

    ASensorInfoSeq getAnalogSensorsMap();
    DSensorInfoSeq getDigitalSensorsMap();  
    
    DigitalIOInfo getDInfo(in SensorInfo si) raises(NameNotFound);
    AnalogIOInfo getAInfo(in SensorInfo si) raises(NameNotFound);


    // -- Функции работы со списком датчиков --
    
    // Для простоты функции сделаны универсальными и не различающими
    // дискретные или аналоговые датчики или выходы


    ASensorInfoSeq getSensorSeq( in UniSetTypes::IDSeq lst );

    struct OutInfo
    {
        SensorInfo si;  
        long value;     
    };

    typedef sequence<OutInfo> OutSeq;

    UniSetTypes::IDSeq setOutputSeq( in OutSeq lst, in UniSetTypes::ObjectId sup_id );


    struct ShortIOInfo
    {
        long value;
        long tv_sec;    
        long tv_usec;   
    };

    ShortIOInfo getChangedTime(in SensorInfo si) raises(NameNotFound);


    struct ShortMap
    {
        UniversalIO::IOTypes type;
        long value;
        long id;
    };

    typedef sequence<ShortMap> ShortMapSeq;

    ShortMapSeq getSensors();
};

// --------------------------------------------------------------------------------------------------------------
interface IONotifyController_i : IOController_i
{
    exception BadRange
    {   
    };


    void askState(in SensorInfo si, in UniSetTypes::ConsumerInfo ci, in UniversalIO::UIOCommand cmd ) raises(NameNotFound,IOBadParam);

    void askValue(in SensorInfo si, in UniSetTypes::ConsumerInfo ci, in UniversalIO::UIOCommand cmd ) raises(NameNotFound,IOBadParam);

    void askSensor(in SensorInfo si, in UniSetTypes::ConsumerInfo ci, in UniversalIO::UIOCommand cmd ) raises(NameNotFound,IOBadParam);

    void askThreshold(in SensorInfo si, in UniSetTypes::ConsumerInfo ci, in UniSetTypes::ThresholdId tid,
                        in long lowLimit, in long hiLimit, in long sensibility,
                        in UniversalIO::UIOCommand cmd ) raises(NameNotFound, IOBadParam, BadRange);


    void askOutput(in SensorInfo si, in UniSetTypes::ConsumerInfo ci, in UniversalIO::UIOCommand cmd ) raises(NameNotFound,IOBadParam);


    UniSetTypes::IDSeq askSensorsSeq( in UniSetTypes::IDSeq lst, 
                                        in UniSetTypes::ConsumerInfo ci,
                                        in UniversalIO::UIOCommand cmd );


    enum ThresholdState
    {
        LowThreshold,       
        NormalThreshold,    
        HiThreshold         
    };

    struct ThresholdInfo
    {
        UniSetTypes::ThresholdId id;
        long hilimit;           
        long lowlimit;          
        long sensibility;       
        ThresholdState state;   
        long tv_sec;            
        long tv_usec;           
        boolean inverse;        
    };

    typedef sequence<ThresholdInfo> ThresholdInfoSeq;
    
    
    struct ThresholdList
    {
        IOController_i::SensorInfo si;
        UniversalIO::IOTypes type;
        long value;
        ThresholdInfoSeq tlist;
    };
    
    typedef sequence<ThresholdList> ThresholdsListSeq;
    ThresholdsListSeq getThresholdsList();

};
// --------------------------------------------------------------------------
#endif